OBJECT Page 77000 Versionning Object Management
{
  OBJECT-PROPERTIES
  {
    Date=01/03/19;
    Time=11:51:08;
    Modified=Yes;
    Version List=TOOL;
  }
  PROPERTIES
  {
    CaptionML=[ENU=Versionning Object Management;
               FRA=Gestionnaire de Versionning objets];
    SaveValues=Yes;
    InsertAllowed=No;
    DeleteAllowed=No;
    ModifyAllowed=Yes;
    SourceTable=Table2000000001;
    SourceTableView=WHERE(Type=FILTER(<>TableData));
    PageType=List;
    OnOpenPage=BEGIN
                 SETRANGE(Modified, TRUE);
                 SETFILTER(Date, '<=%1', TODAY);
                 SETFILTER(ID, '<>%1', 0);
                 SETFILTER("Version List", '*');

                 TimGVersion := 120000T;
                 OptGModifiedAction := OptGModifiedAction::UnCheck;
               END;

    ActionList=ACTIONS
    {
      { 1100267018;  ;ActionContainer;
                      ActionContainerType=ActionItems }
      { 1100267017;1 ;ActionGroup;
                      CaptionML=[ENU=Action;
                                 FRA=Frais et Taxes] }
      { 1100267016;2 ;Action    ;
                      CaptionML=[ENU=Apply Versionning;
                                 FRA=Appliquer versionning];
                      Promoted=Yes;
                      Image=EditLines;
                      OnAction=BEGIN
                                 Version;
                               END;
                                }
    }
  }
  CONTROLS
  {
    { 1100267000;0;Container;
                ContainerType=ContentArea }

    { 1100267019;1;Group  ;
                Name=Version;
                CaptionML=[ENU=Version Apply;
                           FRA=Appliquer Versionning];
                GroupType=Group }

    { 1100267020;2;Field  ;
                Name=VersionDate;
                CaptionML=[ENU=Date;
                           FRA=Date];
                ToolTipML=[ENU=Keep empty to not modify objects date;
                           FRA=Laisser … vide pour ne pas modifier la date des objets];
                SourceExpr=DatGVersion }

    { 1100267021;2;Field  ;
                Name=VersionTime;
                CaptionML=[ENU=Time;
                           FRA=Heure version];
                ToolTipML=[ENU=Keep empty to not modify objectstime;
                           FRA=Laisser … vide pour ne pas modifier l'heure des objets];
                SourceExpr=TimGVersion }

    { 1100267022;2;Field  ;
                Name=VerionText;
                CaptionML=[ENU=Versionning;
                           FRA=Version];
                ToolTipML=[ENU=Must be on 3 caracters + version ex : NAV1.00;
                           FRA=Doit ˆtre sur 3 caractŠres + verson ex : NAV1.00];
                SourceExpr=TxtGLibVersion }

    { 1100267023;2;Field  ;
                CaptionML=[ENU=Modified;
                           FRA=Modifi‚];
                SourceExpr=OptGModifiedAction }

    { 1100267001;1;Group  ;
                Name=Group;
                GroupType=Repeater }

    { 1100267002;2;Field  ;
                SourceExpr=Type }

    { 1100267003;2;Field  ;
                SourceExpr=ID }

    { 1100267004;2;Field  ;
                SourceExpr=Name }

    { 1100267005;2;Field  ;
                SourceExpr=Modified }

    { 1100267006;2;Field  ;
                SourceExpr=Compiled }

    { 1100267007;2;Field  ;
                SourceExpr=Date }

    { 1100267008;2;Field  ;
                SourceExpr=Time }

    { 1100267009;2;Field  ;
                SourceExpr="Version List" }

    { 1100267010;2;Field  ;
                SourceExpr=Caption }

  }
  CODE
  {
    VAR
      DatGVersion@1100267001 : Date;
      TimGVersion@1100267000 : Time;
      TxtGLibVersion@1100267002 : Text[80];
      TxtGDateFilter@1100267004 : Text[50];
      TxtGVersionFilter@1100267003 : Text[200];
      TxtGNoFilter@1100267006 : Text[50];
      CstGTxtG50008@1100267007 : TextConst 'ENU=You will modify Date of all selected Objects.\ Continue ?;FRA=Vous allez modifier la date de tous les objets s‚lectionn‚s.\Voulez vous continuer ?';
      OptGModifiedAction@1100267010 : ' ,UnCheck,Check';
      BooGModifyFilter@1100267005 : Boolean;

    LOCAL PROCEDURE Version@1100267000();
    VAR
      RecLObject@1100267000 : Record 2000000001;
    BEGIN
      IF CONFIRM(CstGTxtG50008) THEN
      BEGIN

        RecLObject.COPYFILTERS(Rec);
        IF RecLObject.FINDFIRST THEN;
        REPEAT
          IF DatGVersion <> 0D THEN
            RecLObject.Date := DatGVersion;

          IF TimGVersion <> 0T THEN
            RecLObject.Time := TimGVersion;

          IF TxtGLibVersion <> '' THEN
            RecLObject."Version List" := COPYSTR(FctTextVersionMgt(RecLObject."Version List",TxtGLibVersion),1,80);

          CASE OptGModifiedAction OF
            OptGModifiedAction::Check:
              RecLObject.Modified := TRUE;
            OptGModifiedAction::UnCheck:
              RecLObject.Modified := FALSE;
           END;
           RecLObject.MODIFY(TRUE)
        UNTIL RecLObject.NEXT = 0;

        IF (OptGModifiedAction <> OptGModifiedAction::" ") THEN
        BEGIN
          RESET;
          Rec.COPYFILTERS(RecLObject);
          BooGModifyFilter := FALSE;
        END;
      END;
    END;

    PROCEDURE FctTextVersionMgt@1000000009(TxtOldVersion@1000000000 : Text;TxtVersion@1000000003 : Text) TxtLVersion : Text;
    VAR
      IntLPosVersion@1000000001 : Integer;
    BEGIN
      //-------------------------
      //Init value Version
      //3 first letter of Version
      //-------------------------
      IntLPosVersion := 0;
      IntLPosVersion := STRPOS(TxtOldVersion,COPYSTR(TxtGLibVersion,1,3));

      IF IntLPosVersion > 0 THEN BEGIN
        TxtLVersion := TxtOldVersion;
      END ELSE
        IF (IntLPosVersion = 0) AND (TxtOldVersion = '') THEN
          TxtLVersion := TxtVersion
        ELSE
          TxtLVersion := COPYSTR(TxtOldVersion + ',' + TxtVersion,1,80);
    END;

    BEGIN
    END.
  }
}